Warning, /epic/CMakeLists.txt is written in an unsupported language. File is not indexed.
0001 cmake_minimum_required(VERSION 3.12 FATAL_ERROR)
0002
0003 # CMP0074: find_package() uses <PackageName>_ROOT variables
0004 cmake_policy(SET CMP0074 NEW)
0005
0006 PROJECT(epic
0007 LANGUAGES CXX
0008 DESCRIPTION "DD4hep Geometry Description of the EPIC Experiment"
0009 )
0010
0011 # C++ standard
0012 set(CMAKE_CXX_STANDARD 17)
0013 set(CMAKE_CXX_STANDARD 17 CACHE STRING "Set the C++ standard to be used")
0014 if(NOT CMAKE_CXX_STANDARD MATCHES "17|20|23")
0015 message(FATAL_ERROR "Unsupported C++ standard: ${CMAKE_CXX_STANDARD}")
0016 endif()
0017 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0018 set(CMAKE_CXX_EXTENSIONS OFF)
0019
0020 # Build type
0021 if (NOT CMAKE_BUILD_TYPE)
0022 set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Build type configuration" FORCE)
0023 message(STATUS "Setting default build type: ${CMAKE_BUILD_TYPE}")
0024 endif()
0025
0026 # Error on all warnings
0027 if(NOT CMAKE_BUILD_TYPE STREQUAL "Release")
0028 add_compile_options(-Wall -Wextra -Werror -pedantic)
0029 endif()
0030
0031 # Export compile commands as json for run-clang-tidy
0032 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
0033
0034 # Install to the top directory by default
0035 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
0036 set(CMAKE_INSTALL_PREFIX ${CMAKE_SOURCE_DIR}/prefix CACHE PATH "Install in $src/prefix/ directory by default" FORCE)
0037 endif()
0038
0039 # Install into GNU standard directories
0040 include(GNUInstallDirs)
0041
0042 # Dependencies
0043 find_package(DD4hep 1.27 REQUIRED COMPONENTS DDCore DDRec)
0044 find_package(fmt REQUIRED)
0045
0046 #-----------------------------------------------------------------------------------
0047 set(a_lib_name ${PROJECT_NAME})
0048
0049 set(DD4HEP_SET_RPATH TRUE)
0050 dd4hep_configure_output(INSTALL ${CMAKE_INSTALL_PREFIX})
0051 dd4hep_set_compiler_flags()
0052
0053 file(GLOB sources CONFIGURE_DEPENDS src/*.cpp)
0054 dd4hep_add_plugin(${a_lib_name}
0055 SOURCES ${sources}
0056 USES ROOT::Core ROOT::Gdml
0057 )
0058 target_link_libraries(${a_lib_name}
0059 PUBLIC DD4hep::DDCore DD4hep::DDRec fmt::fmt
0060 )
0061
0062 #-----------------------------------------------------------------------------------
0063 # Parse jinja templates: once by default, and once for all yml files
0064 set(TEMPLATE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/templates)
0065 set(TEMPLATE_XML ${PROJECT_NAME}.xml.jinja2)
0066
0067 file(GLOB CONFIG_YMLS ${CMAKE_CURRENT_SOURCE_DIR}/configurations/*.yml)
0068 foreach(config_yml ${CONFIG_YMLS})
0069 get_filename_component(config ${config_yml} NAME_WE)
0070 add_custom_target(${config}.xml ALL)
0071 add_custom_command(TARGET ${config}.xml
0072 COMMAND
0073 ${CMAKE_CURRENT_SOURCE_DIR}/bin/make_detector_configuration
0074 --dir ${TEMPLATE_DIR}
0075 --template ${TEMPLATE_XML}
0076 --config ${config_yml}
0077 --output ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}_${config}.xml
0078 COMMENT "Creating configuration ${config} for ${PROJECT_NAME}"
0079 )
0080 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}_${config}.xml
0081 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/
0082 )
0083 endforeach()
0084
0085 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}_full.xml
0086 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/
0087 RENAME ${PROJECT_NAME}.xml
0088 )
0089
0090 #-----------------------------------------------------------------------------------
0091 # Install the detector description files.
0092 install(DIRECTORY compact/
0093 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/compact
0094 FILES_MATCHING PATTERN "*.xml" PATTERN "*.gdml"
0095 )
0096
0097 #-----------------------------------------------------------------------------------
0098 # Install the detector calibration files.
0099 install(DIRECTORY calibrations/
0100 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/calibrations
0101 )
0102
0103 #-----------------------------------------------------------------------------------
0104 # Configure and install detector setup script
0105 #
0106 execute_process(
0107 COMMAND git rev-parse --abbrev-ref HEAD
0108 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
0109 OUTPUT_VARIABLE GIT_BRANCH
0110 OUTPUT_STRIP_TRAILING_WHITESPACE
0111 )
0112 configure_file(templates/setup.sh.in ${CMAKE_CURRENT_BINARY_DIR}/setup.sh @ONLY)
0113 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/setup.sh
0114 DESTINATION ${CMAKE_INSTALL_PREFIX}
0115 )
0116 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/setup.sh
0117 DESTINATION ${CMAKE_INSTALL_BINDIR}
0118 RENAME this${PROJECT_NAME}.sh
0119 )
0120
0121 # install programs
0122 install(PROGRAMS bin/g4MaterialScan_to_csv
0123 DESTINATION ${CMAKE_INSTALL_BINDIR}
0124 )