yall/fullset-c3-repro/download_raw.tcsh

0001 #!/bin/tcsh -f
0002 # Download raw files needed for FullSetC_3.
0003
0004 set SRC = root://dtn-eic.jlab.org:1094//work/eic3/EPIC/TestBeam/LFHCAL/CERN/2026/2026_SPSH2/raw
0005
0006 if ($#argv >= 1) then
0007     set DEST = "$argv[1]"
0008 else if ($?LFHCAL_DATA) then
0009     set DEST = "$LFHCAL_DATA"
0010 else
0011     set DEST = /gpfs/mnt/gpfs01/star/pwg/pnord/eic/2026TBdata
0012 endif
0013
0014 mkdir -p "$DEST"
0015 if ($status != 0) exit 1
0016
0017 foreach r (278 289 290 291 292 293)
0018     set OUT = "$DEST/Run${r}.h2g"
0019     set TMP = "$OUT.part"
0020     if (-s "$OUT") then
0021         echo "Run${r}.h2g already present"
0022         continue
0023     endif
0024     echo "Downloading Run${r}.h2g"
0025     /bin/rm -f "$TMP"
0026     xrdcp "$SRC/Run${r}.h2g" "$TMP"
0027     if ($status != 0) then
0028         echo "ERROR: download failed for Run${r}.h2g"
0029         /bin/rm -f "$TMP"
0030         exit 1
0031     endif
0032     /bin/mv "$TMP" "$OUT"
0033     if ($status != 0) exit 1
0034 end
0035
0036 echo ""
0037 echo "FullSetC_3 raw files:"
0038 foreach r (278 289 290 291 292 293)
0039     ls -lh "$DEST/Run${r}.h2g"
0040 end