Warning, /acts/Detray/cmake/detray-config.cmake.in is written in an unsupported language. File is not indexed.
0001 # This file is part of the ACTS project.
0002 #
0003 # Copyright (C) 2016 CERN for the benefit of the ACTS project
0004 #
0005 # This Source Code Form is subject to the terms of the Mozilla Public
0006 # License, v. 2.0. If a copy of the MPL was not distributed with this
0007 # file, You can obtain one at https://mozilla.org/MPL/2.0/.
0008
0009 # Set up the helper functions/macros.
0010 @PACKAGE_INIT@
0011
0012 # Set up variables describing which components were enabled during the
0013 # Detray build.
0014 set(DETRAY_FASTOR_PLUGIN @DETRAY_FASTOR_PLUGIN@)
0015 set(DETRAY_EIGEN_PLUGIN @DETRAY_EIGEN_PLUGIN@)
0016 set(DETRAY_SMATRIX_PLUGIN @DETRAY_SMATRIX_PLUGIN@)
0017 set(DETRAY_VC_AOS_PLUGIN @DETRAY_VC_AOS_PLUGIN@)
0018 set(DETRAY_VC_SOA_PLUGIN @DETRAY_VC_SOA_PLUGIN@)
0019
0020 set(DETRAY_SVG_DISPLAY @DETRAY_SVG_DISPLAY@)
0021 set(DETRAY_BUILD_TESTING @DETRAY_BUILD_TESTING@)
0022 set(DETRAY_BUILD_TEST_UTILS @DETRAY_BUILD_TEST_UTILS@)
0023 set(DETRAY_BUILD_VALIDATION_TOOLS @DETRAY_BUILD_VALIDATION_TOOLS@)
0024 set(DETRAY_BUILD_BENCHMARKS @DETRAY_BUILD_BENCHMARKS@)
0025 set(DETRAY_BUILD_CLI_TOOLS @DETRAY_BUILD_CLI_TOOLS@)
0026
0027 # Set up some simple variables for using the package.
0028 set(detray_VERSION "@PROJECT_VERSION@")
0029 set_and_check(detray_INCLUDE_DIR "@PACKAGE_CMAKE_INSTALL_INCLUDEDIR@")
0030 set_and_check(detray_CMAKE_DIR "@PACKAGE_CMAKE_INSTALL_CMAKEDIR@")
0031
0032 # Find all packages that Detray needs to function.
0033 include(CMakeFindDependencyMacro)
0034
0035 set(DETRAY_VECMEM_VERSION @DETRAY_VECMEM_VERSION@)
0036 set(DETRAY_NLOHMANN_VERSION @DETRAY_NLOHMANN_VERSION@)
0037
0038 find_dependency(vecmem ${DETRAY_VECMEM_VERSION})
0039 find_dependency(nlohmann_json ${DETRAY_NLOHMANN_VERSION})
0040
0041 if(DETRAY_BUILD_TEST_UTILS OR DETRAY_BUILD_BENCHMARKS)
0042 set(DETRAY_COVFIE_VERSION @DETRAY_COVFIE_VERSION@)
0043 find_dependency(covfie ${DETRAY_COVFIE_VERSION})
0044 endif()
0045
0046 if(DETRAY_SVG_DISPLAY)
0047 set(DETRAY_ACTSVG_VERSION @DETRAY_ACTSVG_VERSION@)
0048 find_dependency(
0049 actsvg
0050 ${DETRAY_ACTSVG_VERSION}
0051 REQUIRED
0052 COMPONENTS
0053 core
0054 meta
0055 )
0056 endif()
0057
0058 if(DETRAY_EIGEN_PLUGIN)
0059 set(DETRAY_EIGEN_VERSION @DETRAY_EIGEN_VERSION@)
0060 find_dependency(Eigen3 ${DETRAY_EIGEN_VERSION})
0061 endif()
0062
0063 if(DETRAY_FASTOR_PLUGIN)
0064 set(DETRAY_FASTOR_VERSION @DETRAY_FASTOR_VERSION@)
0065 find_dependency(Fastor ${DETRAY_FASTOR_VERSION})
0066 endif()
0067
0068 if(DETRAY_SMATRIX_PLUGIN)
0069 find_dependency(ROOT COMPONENTS Smatrix)
0070 endif()
0071
0072 if(DETRAY_VC_AOS_PLUGIN OR DETRAY_VC_SOA_PLUGIN)
0073 set(DETRAY_VC_VERSION @DETRAY_VC_VERSION@)
0074 find_dependency(Vc ${DETRAY_VC_VERSION})
0075 endif()
0076
0077 # Print a standard information message about the package being found.
0078 include(FindPackageHandleStandardArgs)
0079 find_package_handle_standard_args(
0080 detray
0081 REQUIRED_VARS CMAKE_CURRENT_LIST_FILE
0082 VERSION_VAR detray_VERSION
0083 )
0084
0085 # Include the file listing all the imported targets and options.
0086 include("${detray_CMAKE_DIR}/detray-config-targets.cmake")
