Warning, /jana2/cmake/JANAConfig.cmake.in is written in an unsupported language. File is not indexed.
0001 @PACKAGE_INIT@
0002
0003 find_package(Threads REQUIRED)
0004
0005 include("${CMAKE_CURRENT_LIST_DIR}/JANATargets.cmake")
0006
0007 # Make Find* cmake scripts available to downstreams
0008 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}")
0009
0010 # Expose public dependencies
0011 include(CMakeFindDependencyMacro)
0012 set(USE_PODIO @USE_PODIO@)
0013 if(USE_PODIO)
0014 find_dependency(podio REQUIRED)
0015 endif()
0016 set(USE_ROOT @USE_ROOT@)
0017 if(USE_ROOT)
0018 find_dependency(ROOT REQUIRED)
0019 endif()
0020 set(USE_ZEROMQ @USE_ZEROMQ@)
0021 if(USE_ZEROMQ)
0022 find_dependency(ZeroMQ REQUIRED)
0023 endif()
0024
0025 # Provide user with shared libraries by default if JANA was built with them.
0026 # Otherwise, provide them with the static version. They can always specify themselves
0027 # using the JANA::jana2_shared_lib and JANA::jana2_static_lib targets explicitly.
0028 # n.b. this would be cleaner if we could use an ALIAS, but that would require cmake
0029 # 3.18 or greater and we want to support legacy versions at this point.
0030 set(BUILD_SHARED_LIBS @BUILD_SHARED_LIBS@)
0031 if (${BUILD_SHARED_LIBS})
0032 get_target_property(JANA_INCLUDE_DIRS JANA::jana2_shared_lib INTERFACE_INCLUDE_DIRECTORIES)
0033 set(JANA_LIBRARIES JANA::jana2_shared_lib)
0034 else()
0035 get_target_property(JANA_INCLUDE_DIRS JANA::jana2_static_lib INTERFACE_INCLUDE_DIRECTORIES)
0036 set(JANA_LIBRARIES JANA::jana2_static_lib)
0037 endif()
0038
0039 # There are some issues with the include directories being passed through as a property
0040 # of the imported targets. This shows up as JANA_INCLUDE_DIRS being set to
0041 # "JANA_INCLUDE_DIRS-NOTFOUND". As a workaround, if "NOTFOUND" is included in
0042 # JANA_INCLUDE_DIRS then overwrite it here with what it should have been set to.
0043 if(${JANA_INCLUDE_DIRS} MATCHES "NOTFOUND")
0044 set(JANA_INCLUDE_DIRS @CMAKE_INSTALL_PREFIX@/include)
0045 endif()
0046
0047 # Backwards compatibility
0048 set(JANA_INCLUDE_DIR ${JANA_INCLUDE_DIRS})
0049 set(JANA_LIBRARY ${JANA_LIBRARIES})
0050 set(JANA_LIB ${JANA_LIBRARIES})
0051
0052 # Include JANA cmake helper macros
0053 include("${CMAKE_CURRENT_LIST_DIR}/AddJanaPlugin.cmake")
0054 include("${CMAKE_CURRENT_LIST_DIR}/AddJanaLibrary.cmake")
0055 include("${CMAKE_CURRENT_LIST_DIR}/AddJanaTest.cmake")
0056
0057
