Warning, /epic/CMakeLists.txt is written in an unsupported language. File is not indexed.
0001 cmake_minimum_required(VERSION 3.12 FATAL_ERROR)
0002
0003 # CMP0074: find_package() uses <PackageName>_ROOT variables
0004 cmake_policy(SET CMP0074 NEW)
0005
0006 PROJECT(epic
0007 LANGUAGES CXX
0008 DESCRIPTION "DD4hep Geometry Description of the EPIC Experiment"
0009 )
0010
0011 # Set version based on git
0012 include(cmake/git_version.cmake)
0013 set_git_version(CMAKE_PROJECT_VERSION)
0014
0015 # C++ standard
0016 set(CMAKE_CXX_STANDARD 17)
0017 set(CMAKE_CXX_STANDARD 17 CACHE STRING "Set the C++ standard to be used")
0018 if(NOT CMAKE_CXX_STANDARD MATCHES "17|20|23")
0019 message(FATAL_ERROR "Unsupported C++ standard: ${CMAKE_CXX_STANDARD}")
0020 endif()
0021 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0022 set(CMAKE_CXX_EXTENSIONS OFF)
0023
0024 # Build type
0025 if (NOT CMAKE_BUILD_TYPE)
0026 set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Build type configuration" FORCE)
0027 message(STATUS "Setting default build type: ${CMAKE_BUILD_TYPE}")
0028 endif()
0029
0030 # Error on all warnings
0031 if(NOT CMAKE_BUILD_TYPE STREQUAL "Release")
0032 add_compile_options(-Wall -Wextra -Werror -pedantic)
0033 endif()
0034
0035 # Export compile commands as json for run-clang-tidy
0036 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
0037
0038 # Install to the top directory by default
0039 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
0040 set(CMAKE_INSTALL_PREFIX ${CMAKE_SOURCE_DIR}/prefix CACHE PATH "Install in $src/prefix/ directory by default" FORCE)
0041 endif()
0042
0043 # Install into GNU standard directories
0044 include(GNUInstallDirs)
0045
0046 # Dependencies
0047 find_package(DD4hep 1.27 REQUIRED COMPONENTS DDCore DDRec)
0048 find_package(fmt REQUIRED)
0049 find_package(IRT2 2.1.1)
0050
0051 #-----------------------------------------------------------------------------------
0052 set(a_lib_name ${PROJECT_NAME})
0053
0054 set(DD4HEP_SET_RPATH TRUE)
0055 dd4hep_configure_output(INSTALL ${CMAKE_INSTALL_PREFIX})
0056 dd4hep_set_compiler_flags()
0057
0058 file(GLOB sources CONFIGURE_DEPENDS src/*.cpp)
0059
0060 dd4hep_add_plugin(${a_lib_name}
0061 SOURCES ${sources}
0062 USES ROOT::Core ROOT::Gdml
0063 )
0064 target_link_libraries(${a_lib_name}
0065 PUBLIC DD4hep::DDCore DD4hep::DDRec fmt::fmt
0066 )
0067 set(WITH_IRT1_SUPPORT TRUE CACHE STRING "Enable constant definitions used by EICrecon integration in IRT1")
0068 if(WITH_IRT1_SUPPORT)
0069 target_compile_definitions(${a_lib_name} PRIVATE WITH_IRT1_SUPPORT)
0070 endif()
0071 if(IRT2_FOUND)
0072 target_compile_definitions(${a_lib_name} PRIVATE WITH_IRT2_SUPPORT)
0073 target_link_libraries(${a_lib_name} PRIVATE IRT2)
0074 endif()
0075
0076 #-----------------------------------------------------------------------------------
0077 # Parse jinja templates: once by default, and once for all yml files
0078 set(TEMPLATE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/templates)
0079 set(TEMPLATE_XML ${PROJECT_NAME}.xml.jinja2)
0080
0081 file(GLOB CONFIG_YMLS ${CMAKE_CURRENT_SOURCE_DIR}/configurations/*.yml)
0082 foreach(config_yml ${CONFIG_YMLS})
0083 get_filename_component(config ${config_yml} NAME_WE)
0084 add_custom_target(${config}.xml ALL)
0085 add_custom_command(TARGET ${config}.xml POST_BUILD
0086 COMMAND
0087 ${CMAKE_CURRENT_SOURCE_DIR}/bin/make_detector_configuration
0088 --dir ${TEMPLATE_DIR}
0089 --template ${TEMPLATE_XML}
0090 --config ${config_yml}
0091 --output ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}_${config}.xml
0092 COMMENT "Creating configuration ${config} for ${PROJECT_NAME}"
0093 )
0094 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}_${config}.xml
0095 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/
0096 )
0097 endforeach()
0098
0099 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}_full.xml
0100 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/
0101 RENAME ${PROJECT_NAME}.xml
0102 )
0103
0104 #-----------------------------------------------------------------------------------
0105 # Install the detector description files.
0106 install(DIRECTORY compact/
0107 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/compact
0108 FILES_MATCHING PATTERN "*.xml" PATTERN "*.gdml"
0109 )
0110
0111 #-----------------------------------------------------------------------------------
0112 # Install the detector calibration files.
0113 install(DIRECTORY calibrations/
0114 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/calibrations
0115 )
0116
0117 #-----------------------------------------------------------------------------------
0118 # Configure and install compact/version.xml
0119 #
0120 configure_file(templates/version.xml.in ${CMAKE_CURRENT_BINARY_DIR}/version.xml @ONLY)
0121 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/version.xml
0122 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/compact
0123 )
0124
0125 #-----------------------------------------------------------------------------------
0126 # Configure and install detector setup script
0127 #
0128 configure_file(templates/thisepic.sh.in ${CMAKE_CURRENT_BINARY_DIR}/thisepic.sh @ONLY)
0129 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/thisepic.sh
0130 DESTINATION ${CMAKE_INSTALL_BINDIR}
0131 )
0132 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/thisepic.sh
0133 DESTINATION ${CMAKE_INSTALL_PREFIX}
0134 RENAME setup.sh
0135 )
0136
0137 # install programs
0138 install(PROGRAMS bin/g4MaterialScan_to_csv
0139 DESTINATION ${CMAKE_INSTALL_BINDIR}
0140 )
