Warning, /acts/Examples/Framework/CMakeLists.txt is written in an unsupported language. File is not indexed.
0001 include(ActsTargetLinkLibrariesSystem)
0002
0003 acts_add_library(
0004 ExamplesFramework
0005 src/EventData/MuonSpacePoint.cpp
0006 src/EventData/MuonSpacePointCalibrator.cpp
0007 src/EventData/IndexSourceLink.cpp
0008 src/EventData/Measurement.cpp
0009 src/EventData/MeasurementCalibration.cpp
0010 src/EventData/SimParticle.cpp
0011 src/EventData/Jets.cpp
0012 src/EventData/SeedSpacePointSelection.cpp
0013 src/Framework/IAlgorithm.cpp
0014 src/Framework/SequenceElement.cpp
0015 src/Framework/WhiteBoard.cpp
0016 src/Framework/RandomNumbers.cpp
0017 src/Framework/Sequencer.cpp
0018 src/Framework/DataHandle.cpp
0019 src/Framework/BufferedReader.cpp
0020 src/Utilities/EventDataTransforms.cpp
0021 src/Utilities/Paths.cpp
0022 src/Utilities/Options.cpp
0023 src/Utilities/ParametricParticleGenerator.cpp
0024 src/Utilities/StripModulePairing.cpp
0025 src/Utilities/VertexTruthUtility.cpp
0026 src/Validation/DuplicationPlotTool.cpp
0027 src/Validation/EffPlotTool.cpp
0028 src/Validation/FakePlotTool.cpp
0029 src/Validation/HistogramFit.cpp
0030 src/Validation/ParametersOnSurface.cpp
0031 src/Validation/ResPlotTool.cpp
0032 src/Validation/TrackClassification.cpp
0033 src/Validation/PatternRecognitionPerformanceCollector.cpp
0034 src/Validation/TrackParameterPerformanceCollector.cpp
0035 src/Validation/TrackQualityPlotTool.cpp
0036 src/Validation/TrackSummaryPlotTool.cpp
0037 ACTS_INCLUDE_FOLDER include/ActsExamples
0038 )
0039
0040 target_include_directories(
0041 ActsExamplesFramework
0042 PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
0043 )
0044 target_link_libraries(
0045 ActsExamplesFramework
0046 PUBLIC Acts::Fatras Acts::PluginFpeMonitoring Boost::boost HepMC3::HepMC3
0047 )
0048 target_compile_definitions(
0049 ActsExamplesFramework
0050 PRIVATE BOOST_FILESYSTEM_NO_DEPRECATED
0051 )
0052
0053 acts_compile_headers(
0054 ExamplesFramework
0055 GLOB
0056 include/ActsExamples/Framework/*.hpp
0057 include/ActsExamples/EventData/*.hpp
0058 include/ActsExamples/Root/*.hpp
0059 include/ActsExamples/Utilities/*.hpp
0060 include/ActsExamples/Validation/*.hpp
0061 )
0062
0063 # Plugin-dependent framework components
0064 # Note that due to conditional compilation the headers of ROOT/Onnx components
0065 # get installed regardless of the configuration which could lead to link errors
0066 # in case one includes these files without building the components.
0067 if(ACTS_BUILD_EXAMPLES_ROOT)
0068 target_sources(
0069 ActsExamplesFramework
0070 PRIVATE src/Root/ScalingCalibrator.cpp src/Root/MuonVisualization.cpp
0071 )
0072 target_link_libraries(
0073 ActsExamplesFramework
0074 PUBLIC ROOT::Core ROOT::Hist ROOT::Graf ROOT::Gpad
0075 )
0076 set_source_files_properties(
0077 src/Framework/Sequencer.cpp
0078 TARGET
0079 ActsExamplesFramework
0080 PROPERTIES COMPILE_DEFINITIONS ACTS_BUILD_EXAMPLES_ROOT
0081 )
0082 endif()
0083
0084 if(ACTS_BUILD_PLUGIN_ONNX)
0085 target_sources(ActsExamplesFramework PRIVATE src/Onnx/NeuralCalibrator.cpp)
0086 target_link_libraries(ActsExamplesFramework PUBLIC Acts::PluginOnnx)
0087 acts_compile_headers(ExamplesFramework GLOB include/ActsExamples/Onnx/*.hpp)
0088 endif()
0089
0090 # newer DD4hep version require TBB and search internally for TBB in
0091 # config-only mode. to avoid mismatches we explicitly search using
0092 # config-only mode first to be sure that we find the same version.
0093 find_package(TBB ${_acts_tbb_version} CONFIG)
0094
0095 if(NOT TBB_FOUND)
0096 # no version check possible when using the find module
0097 find_package(TBB ${_acts_tbb_version} MODULE REQUIRED)
0098 endif()
0099
0100 target_link_libraries(ActsExamplesFramework PUBLIC TBB::tbb)
