Warning, /EICrecon/CMakeLists.txt is written in an unsupported language. File is not indexed.
0001 # cmake-format: off
0002 #
0003 # Variables to control this CMake build:
0004 # ===================================================================================
0005 # CMake flag | environment variable | Description
0006 # ===================================================================================
0007 # -- (under review) | EDM4HEP_ROOT | Edm4Hep installation directory
0008 #------------------------------------------------------------------------------------
0009 # -DCMAKE_CXX_STANDARD | 17 - standard for C++ compilation
0010 # ===================================================================================
0011 #
0012 #
0013 # ==============================================================
0014 # DEPENDENCIES (used by find_package)
0015 # ==============================================================
0016 # Name | Description
0017 # ==============================================================
0018 # JANA | Jana2 framework
0019 # EDM4HEP | Event data model based on podio
0020 # podio | IO library
0021 # DD4hep | Geometry framework
0022 # ROOT | CERN ROOT
0023 # spdlog | Formatting library
0024 # IRT | Indirect Ray Tracing library
0025 # ==============================================================
0026 #
0027 # cmake-format: on
0028
0029 cmake_minimum_required(VERSION 3.24)
0030
0031 # 3.27: find_package() uses upper-case <PACKAGENAME>_ROOT variables
0032 cmake_policy(SET CMP0144 NEW)
0033
0034 project(EICrecon LANGUAGES CXX)
0035
0036 # CMake includes
0037 include(CheckCXXCompilerFlag)
0038
0039 # Set version based on git
0040 include(cmake/git_version.cmake)
0041 set_git_version(CMAKE_PROJECT_VERSION)
0042
0043 # Set a default build type if none was specified
0044 set(default_build_type "Release")
0045 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
0046 message(
0047 STATUS
0048 "Setting build type to '${default_build_type}' as none was specified.")
0049 set(CMAKE_BUILD_TYPE
0050 "${default_build_type}"
0051 CACHE STRING "Choose the type of build." FORCE)
0052 # Set the possible values of build type for cmake-gui
0053 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
0054 "MinSizeRel" "RelWithDebInfo")
0055 endif()
0056
0057 # Minimal dependency versions
0058 set(Acts_VERSION_MIN 36.0.0)
0059 set(algorithms_VERSION_MIN 1.0.0)
0060 set(DD4hep_VERSION_MIN 1.21)
0061 set(EDM4EIC_VERSION_MIN 8.0)
0062 set(EDM4HEP_VERSION_MIN 0.99.0)
0063 set(Eigen3_VERSION_MIN 3.3)
0064 set(FastJet_VERSION_MIN 3)
0065 set(FastJetContrib_VERSION_MIN 1.46)
0066 set(fmt_VERSION_MIN 9.0.0)
0067 set(IRT_VERSION_MIN 1.0.5)
0068 set(JANA_VERSION_MIN 2.2.0)
0069 set(onnxruntime_MIN_VERSION 1.17)
0070 set(podio_VERSION_MIN 0.17)
0071 set(ROOT_VERSION_MIN 6.28)
0072 set(spdlog_VERSION_MIN 1.11.0)
0073
0074 # Set default standard to C++20
0075 set(CMAKE_CXX_STANDARD_MIN 20)
0076 set(CMAKE_CXX_STANDARD
0077 ${CMAKE_CXX_STANDARD_MIN}
0078 CACHE STRING "C++ standard to be used")
0079 if(CMAKE_CXX_STANDARD LESS CMAKE_CXX_STANDARD_MIN)
0080 message(
0081 FATAL_ERROR
0082 "Unsupported C++ standard: ${CMAKE_CXX_STANDARD} (at least ${CMAKE_CXX_STANDARD_MIN} required)"
0083 )
0084 endif()
0085 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0086 set(CMAKE_CXX_EXTENSIONS OFF)
0087
0088 # Infrastructure to support use of --no-as-needed
0089 include(CheckLinkerFlag)
0090 check_linker_flag(CXX "LINKER:--no-as-needed" CXX_LINKER_HAS_no_as_needed)
0091 set(CMAKE_CXX_LINK_LIBRARY_USING_NO_AS_NEEDED_SUPPORTED TRUE)
0092 set(CMAKE_CXX_LINK_LIBRARY_USING_NO_AS_NEEDED
0093 "LINKER:--push-state,--no-as-needed" "<LINK_ITEM>" "LINKER:--pop-state")
0094
0095 # Export compile commands as json for run-clang-tidy
0096 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
0097
0098 # Also use clang-tidy integration in CMake
0099 option(ENABLE_CLANG_TIDY "Enable clang-tidy integration in cmake" OFF)
0100 if(ENABLE_CLANG_TIDY)
0101 find_program(CLANG_TIDY_EXE NAMES "clang-tidy")
0102 if(CLANG_TIDY_EXE)
0103 message(STATUS "clang-tidy found: ${CLANG_TIDY_EXE}")
0104 set(CMAKE_CXX_CLANG_TIDY
0105 "${CLANG_TIDY_EXE}"
0106 CACHE STRING "" FORCE)
0107 else()
0108 set(CMAKE_CXX_CLANG_TIDY
0109 ""
0110 CACHE STRING "" FORCE)
0111 endif()
0112 endif()
0113
0114 # LINK_WHAT_YOU_USE support
0115 option(ENABLE_LINK_WHAT_YOU_USE
0116 "Enable LINK_WHAT_YOU_USE to detect unnecessary link dependencies" OFF)
0117 if(ENABLE_LINK_WHAT_YOU_USE)
0118 message(STATUS "LINK_WHAT_YOU_USE enabled")
0119 set(CMAKE_LINK_WHAT_YOU_USE TRUE)
0120
0121 # Set output directory for LINK_WHAT_YOU_USE logs
0122 set(LINK_WHAT_YOU_USE_OUTPUT_DIR "${CMAKE_BINARY_DIR}/link_what_you_use_logs")
0123
0124 # Set up custom check script for better output control; CMake will append the
0125 # binary file path as the last argument
0126 set(CMAKE_LINK_WHAT_YOU_USE_CHECK
0127 "${CMAKE_COMMAND}" "-DOUTPUT_DIR=${LINK_WHAT_YOU_USE_OUTPUT_DIR}" -P
0128 "${CMAKE_SOURCE_DIR}/cmake/link_what_you_use_check.cmake")
0129
0130 message(
0131 STATUS
0132 "LINK_WHAT_YOU_USE logs will be written to: ${LINK_WHAT_YOU_USE_OUTPUT_DIR}"
0133 )
0134 endif()
0135
0136 # Enable -fPIC for all targets
0137 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
0138
0139 # Install to the top directory by default
0140 if(${CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT})
0141 set(CMAKE_INSTALL_PREFIX
0142 ${CMAKE_SOURCE_DIR}
0143 CACHE PATH "Install in top directory by default" FORCE)
0144 endif()
0145
0146 # Install to standard location
0147 include(GNUInstallDirs)
0148
0149 # Default plugins installation directory is 'plugins'
0150 if(NOT DEFINED PLUGIN_OUTPUT_DIRECTORY)
0151 set(PLUGIN_OUTPUT_DIRECTORY "lib/${PROJECT_NAME}/plugins")
0152 message(STATUS "${CMAKE_PROJECT_NAME}: Set default PLUGIN_OUTPUT_DIRECTORY")
0153 endif()
0154 message(
0155 STATUS
0156 "${CMAKE_PROJECT_NAME}: PLUGIN_OUTPUT_DIRECTORY: ${PLUGIN_OUTPUT_DIRECTORY}"
0157 )
0158
0159 # Default plugins static libraries installation directory is 'lib'
0160 if(NOT DEFINED PLUGIN_LIBRARY_OUTPUT_DIRECTORY)
0161 set(PLUGIN_LIBRARY_OUTPUT_DIRECTORY "lib")
0162 message(STATUS "${CMAKE_PROJECT_NAME}: Set default PLUGIN_OUTPUT_DIRECTORY")
0163 endif()
0164 message(
0165 STATUS
0166 "${CMAKE_PROJECT_NAME}: PLUGIN_LIBRARY_OUTPUT_DIRECTORY: ${PLUGIN_LIBRARY_OUTPUT_DIRECTORY}"
0167 )
0168
0169 # Use, i.e. don't skip the full RPATH for the build tree, and use relative paths
0170 # for relocatable build products
0171 set(CMAKE_SKIP_BUILD_RPATH FALSE)
0172 set(CMAKE_BUILD_RPATH_USE_ORIGIN TRUE)
0173
0174 # When building, don't use the install RPATH already (but later on when
0175 # installing)
0176 set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
0177 set(CMAKE_SKIP_INSTALL_RPATH FALSE)
0178 set(CMAKE_INSTALL_RPATH
0179 "${CMAKE_INSTALL_PREFIX}/${PLUGIN_LIBRARY_OUTPUT_DIRECTORY};${CMAKE_INSTALL_PREFIX}/${PLUGIN_OUTPUT_DIRECTORY}"
0180 )
0181
0182 # Add the automatically determined parts of the RPATH which point to directories
0183 # outside the build tree to the install RPATH
0184 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
0185
0186 # Check and print what JANA2 is used
0187 find_package(JANA ${JANA_VERSION_MIN} REQUIRED)
0188 message(STATUS "${CMAKE_PROJECT_NAME}: JANA2 CMake : ${JANA_DIR}")
0189 message(STATUS "${CMAKE_PROJECT_NAME}: JANA2 includes: ${JANA_INCLUDE_DIR}")
0190 message(STATUS "${CMAKE_PROJECT_NAME}: JANA2 library : ${JANA_LIBRARY}")
0191
0192 # Algorithms
0193 find_package(algorithms ${algorithms_VERSION_MIN} REQUIRED Core)
0194
0195 # PODIO, EDM4HEP, EDM4EIC event models
0196 find_package(Eigen3 ${Eigen3_VERSION_MIN} REQUIRED)
0197 find_package(podio ${podio_VERSION_MIN} QUIET)
0198 if(NOT podio_FOUND)
0199 find_package(podio 1.0 REQUIRED)
0200 endif()
0201 find_package(EDM4HEP ${EDM4HEP_VERSION_MIN} REQUIRED)
0202 find_package(EDM4EIC ${EDM4EIC_VERSION_MIN} REQUIRED)
0203
0204 # fmt
0205 find_package(fmt ${fmt_VERSION_MIN} REQUIRED)
0206
0207 # spdlog
0208 find_package(spdlog ${spdlog_VERSION_MIN} REQUIRED)
0209
0210 # Guidelines Support Library
0211 find_package(Microsoft.GSL CONFIG)
0212
0213 # Remove PODIO_JSON_OUTPUT (ref: https://github.com/AIDASoft/podio/issues/475)
0214 get_target_property(EDM4HEP_INTERFACE_COMPILE_DEFINITIONS EDM4HEP::edm4hep
0215 INTERFACE_COMPILE_DEFINITIONS)
0216 if(EDM4HEP_INTERFACE_COMPILE_DEFINITIONS)
0217 list(FILTER EDM4HEP_INTERFACE_COMPILE_DEFINITIONS EXCLUDE REGEX
0218 [[^PODIO_JSON_OUTPUT$]])
0219 set_property(
0220 TARGET EDM4HEP::edm4hep PROPERTY INTERFACE_COMPILE_DEFINITIONS
0221 ${EDM4HEP_INTERFACE_COMPILE_DEFINITIONS})
0222 endif()
0223 get_target_property(EDM4EIC_INTERFACE_COMPILE_DEFINITIONS EDM4EIC::edm4eic
0224 INTERFACE_COMPILE_DEFINITIONS)
0225 if(EDM4EIC_INTERFACE_COMPILE_DEFINITIONS)
0226 list(FILTER EDM4EIC_INTERFACE_COMPILE_DEFINITIONS EXCLUDE REGEX
0227 [[^PODIO_JSON_OUTPUT$]])
0228 set_property(
0229 TARGET EDM4EIC::edm4eic PROPERTY INTERFACE_COMPILE_DEFINITIONS
0230 ${EDM4EIC_INTERFACE_COMPILE_DEFINITIONS})
0231 endif()
0232
0233 # DD4Hep is required for the most of the part
0234 find_package(DD4hep ${DD4hep_VERSION_MIN} REQUIRED)
0235
0236 # ACTS cmake-lint: disable=C0103
0237 find_package(Acts REQUIRED COMPONENTS Core PluginDD4hep PluginJson)
0238 set(Acts_VERSION
0239 "${Acts_VERSION_MAJOR}.${Acts_VERSION_MINOR}.${Acts_VERSION_PATCH}")
0240 if(${Acts_VERSION} VERSION_LESS ${Acts_VERSION_MIN})
0241 message(
0242 FATAL_ERROR
0243 "Acts version ${Acts_VERSION_MIN} or higher required, but ${Acts_VERSION} found"
0244 )
0245 endif()
0246 if(${Acts_VERSION} VERSION_GREATER_EQUAL "43.0.0")
0247 set(Acts_NAMESPACE_PREFIX Acts::)
0248 else()
0249 set(Acts_NAMESPACE_PREFIX Acts)
0250 endif()
0251 # Acts::Core
0252 get_target_property(ACTS_COMPILE_FEATURES ${Acts_NAMESPACE_PREFIX}Core
0253 INTERFACE_COMPILE_FEATURES)
0254 if(NOT "cxx_std_${CMAKE_CXX_STANDARD}" IN_LIST ACTS_COMPILE_FEATURES)
0255 message(
0256 WARNING
0257 "Acts has not been built with the requested C++ standard ${CMAKE_CXX_STANDARD}."
0258 )
0259 endif()
0260
0261 # ROOT
0262 find_package(ROOT ${ROOT_VERSION_MIN} REQUIRED)
0263 # Check that ROOT is compiled with a modern enough c++ standard
0264 get_target_property(ROOT_COMPILE_FEATURES ROOT::Core INTERFACE_COMPILE_FEATURES)
0265 if(NOT "cxx_std_${CMAKE_CXX_STANDARD}" IN_LIST ROOT_COMPILE_FEATURES)
0266 message(
0267 WARNING
0268 "ROOT has not been built with the requested C++ standard ${CMAKE_CXX_STANDARD}."
0269 )
0270 endif()
0271
0272 # ONNX Runtime
0273 find_package(onnxruntime ${onnxruntime_MIN_VERSION} CONFIG)
0274
0275 # Add CMake additional functionality:
0276 include(cmake/jana_plugin.cmake) # Add common settings for plugins
0277 list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake) # Find
0278 # Find<Modules>.cmake
0279
0280 enable_testing()
0281
0282 # Address sanitizer
0283 option(USE_ASAN "Compile with address sanitizer" OFF)
0284 if(${USE_ASAN})
0285 add_compile_options(-fsanitize=address -fno-omit-frame-pointer -g -O1)
0286 add_link_options(-fsanitize=address)
0287 install(FILES .github/asan.supp .github/lsan.supp
0288 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME})
0289 endif()
0290
0291 # Thread sanitizer
0292 option(USE_TSAN "Compile with thread sanitizer" OFF)
0293 if(${USE_TSAN})
0294 add_compile_options(-fsanitize=thread -g -O1)
0295 add_link_options(-fsanitize=thread)
0296 install(FILES .github/tsan.supp
0297 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME})
0298 endif()
0299
0300 # Undefined behavior sanitizer
0301 option(USE_UBSAN "Compile with undefined behavior sanitizer" OFF)
0302 if(${USE_UBSAN})
0303 foreach(sanitizer undefined float-divide-by-zero unsigned-integer-overflow
0304 implicit-conversion local-bounds nullability)
0305 check_cxx_compiler_flag("-fsanitize=${sanitizer}"
0306 CXX_COMPILER_HAS_sanitize_${sanitizer})
0307 if(CXX_COMPILER_HAS_sanitize_${sanitizer})
0308 add_compile_options(-fsanitize=${sanitizer})
0309 add_link_options(-fsanitize=${sanitizer})
0310 endif()
0311 endforeach()
0312 add_compile_options(-g -O1)
0313 install(FILES .github/ubsan.supp
0314 DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME})
0315 endif()
0316
0317 # Compress debug symbols if supported
0318 check_cxx_compiler_flag("-gz" CXX_COMPILER_HAS_gz)
0319 if(CXX_COMPILER_HAS_gz)
0320 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -gz")
0321 set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} -gz")
0322 endif()
0323
0324 add_subdirectory(src/services)
0325 add_subdirectory(src/algorithms)
0326 add_subdirectory(src/benchmarks)
0327 add_subdirectory(src/detectors)
0328 add_subdirectory(src/extensions)
0329 add_subdirectory(src/factories)
0330 add_subdirectory(src/global)
0331 add_subdirectory(src/scripts)
0332 add_subdirectory(src/tests)
0333 add_subdirectory(src/utilities)
0334
0335 # Install all cmake helpers
0336 include(CMakePackageConfigHelpers)
0337 configure_package_config_file(
0338 cmake/${PROJECT_NAME}Config.cmake.in
0339 ${CMAKE_CURRENT_BINARY_DIR}/cmake/${PROJECT_NAME}Config.cmake
0340 INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
0341 write_basic_package_version_file(
0342 ${CMAKE_CURRENT_BINARY_DIR}/cmake/${PROJECT_NAME}ConfigVersion.cmake
0343 VERSION ${CMAKE_PROJECT_VERSION}
0344 COMPATIBILITY SameMajorVersion)
0345 install(
0346 FILES ${CMAKE_CURRENT_BINARY_DIR}/cmake/${PROJECT_NAME}Config.cmake
0347 ${CMAKE_CURRENT_BINARY_DIR}/cmake/${PROJECT_NAME}ConfigVersion.cmake
0348 DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
0349 install(
0350 EXPORT ${PROJECT_NAME}Targets
0351 NAMESPACE ${PROJECT_NAME}::
0352 DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
0353 install(
0354 DIRECTORY cmake/
0355 DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
0356 FILES_MATCHING
0357 PATTERN *.cmake)
